FLASH備忘６｜ActionScriptやらWordPressやらを楽しむ会

 
角度のついた線との衝突判定。線が複数版です。

このFLASHの特徴はについて

• 線はランダムに配置、長さもランダム
• ボールが一定時間そこにとどまると初期位置に戻る
• 奇跡を表示します。
• 線と壁で跳ね返ります。

うまく動いたのですが、色々と値をいじっていると不自然なところがあります。
線10本。一見、エラーが内容に見えますが、線を増やすとエラーが目立ちます。


続いて、複数80本。線と下からの衝突に注目。


線の下方向からボールが当たると、突き抜ける現象があります。



最後に、ボールが大きいと、線がボールの大きさを認識してくれないバグ

var bounce:Number = -0.7;
var gravity:Number = 0.3;
var numLines:Number = 10;
var friction:Number = 0.99;
var ball:Ball = new Ball(10);
var count:int = 0;
var xball:Number = 0;
var yball:Number = 0;
var ballvx:Number = 100;
var ballvy:Number = 100;

addChild(ball);
ball.x = stage.stageWidth/2;
ball.y = 10;

//配列に線の作成と格納
var lines:Array = new Array();
for (var i:int=0; i<numLines; i++) {
 var line:Sprite = new Sprite();
 line.graphics.lineStyle(3,Math.random()*0xffffff);
 line.graphics.moveTo(0, 0);
 line.graphics.lineTo(140*Math.random()+80, 0);
 addChild(line);
 lines.push(line);
}

//線の配置処理
for (i = 0; i<numLines; i++) {
 lines[i].x = Math.random()*470;
 lines[i].y = Math.random()*350+50;
 lines[i].rotation = Math.random()*120-60;
}

//フレーム毎のイベントの追加
addEventListener(Event.ENTER_FRAME, onEnterFrame);
function onEnterFrame(e:Event):void {

 ball.vy += gravity;

 ball.vx *= friction;
 ball.vy *= friction;

 ball.x += ball.vx;
 ball.y += ball.vy;

 var right:Number = stage.stageWidth;
 var bottom:Number = stage.stageHeight;
 var r:Number = ball.radius;

 //壁との跳ね返り処理
 if (ball.x < r) {
  ball.x = r;
  ball.vx *= bounce;
 } else if (right - r < ball.x) {
  ball.x = right - r ;
  ball.vx *= bounce;
 }
 if (ball.y < r) {
  ball.y = r;
  ball.vy *= bounce;
 } else if (bottom - r < ball.y) {
  ball.y = bottom - r;
  ball.vy *= bounce;
 }
 //奇跡の表示
 graphics.beginFill(0x00cc00);
 graphics.drawCircle(ball.x, ball.y ,1);

 //線との衝突チェックの開始
 for (var i:int = 0; i<numLines; i++) {
  checkLine(lines[i]);
 }
 
// //画面上に速度を表示する。
// t1_txt.text = String(Math.round(ball.vx*100)/100);
// t2_txt.text = String(Math.round(ball.vy*100)/100);
 //t1.text = String("aaa");
 
 //フレームをカウントして一定時間移動がなければ、初期値にもどす
 count++;
 if (count>60) {
  count = 0;
  ballvx = ball.x - xball;
  ballvy = ball.y - yball;
  if (Math.abs(ballvx) < 5 && Math.abs(ballvy) < 5) {
   ball.x = stage.stageWidth*Math.random();
   ball.y = 10;
   ball.vx = 0;
   ball.vy = 0;
  }
  xball = ball.x;
  yball = ball.y;
 }
}

//チェック処理
function checkLine(line:Sprite):void {

 //線の大きさの取得
 var bounds:Rectangle = line.getBounds(this);
 if (ball.x > bounds.left && ball.x < bounds.right) {

  var angle:Number = line.rotation * Math.PI/180;
  var cos:Number = Math.cos(angle);
  var sin:Number = Math.sin(angle);

  var x1:Number = ball.x - line.x;
  var y1:Number = ball.y - line.y;

  var y2:Number = cos * y1 - sin * x1;
  var vy1:Number = cos * ball.vy - sin * ball.vx;

  //衝突時の処理
  if (y2 > -ball.height/2 && y2 < vy1) {

   var x2:Number = cos * x1 + sin * y1;

   var vx1:Number = cos * ball.vx + sin * ball.vy;
   y2 = -ball.height/2;
   vy1 *= bounce;

   x1 = cos * x2 - sin * y2;
   y1 = cos * y2 + sin * x2;
   ball.vx = cos * vx1 - sin * vy1;
   ball.vy = cos * vy1 + sin * vx1;
   ball.x = line.x + x1;
   ball.y = line.y + y1;
  }
 }
}

 

アップしてから気付いたのですが、fps（フレーム毎秒）が120のままでした（汗）

角度のついた面の跳ね返りです。

スクリプトの処理としては、計算で一度水平に戻して跳ね返りを計算しています。

特徴

• ボールの色はランダムに変化します。
• 初期速度は適切な値でランダム
• 小さいボールはよく弾みます。
• 大きなボールはあまり弾みません。

var gravity:Number = 0.5;
var bounce:Number = -0.3;

var ball:Ball = new Ball();
addChild(ball);
ball.x = 500;
ball.y = -30;
ball.vx = -10;
ball.vy = 5;

var line:Sprite = new Sprite();
line.graphics.lineStyle(1);
line.graphics.moveTo(-300, 0);
line.graphics.lineTo(600, 0);
addChild(line);
line.x = 50;
line.y = 200;
line.rotation = 30;
addEventListener(Event.ENTER_FRAME, onEnterFrame);
function onEnterFrame(e:Event):void {
 if(ball.y > 450){
  var ran:Number = Math.random();
  bounce = -0.8 * (1-ran);
  ball.scaleX = ball.scaleY = ran * 2;
  ball.transform.colorTransform = new ColorTransform(0, 0, 0, 1, Math.random()*255, Math.random()*255, Math.random()*255, 0);
   
  ball.y = -30;
  ball.x = 500;
  ball.vx = -(Math.random()*10+3);
  ball.vy = Math.random()*10-5;
  }
 
 ball.vy += gravity;
 ball.x += ball.vx;
 ball.y += ball.vy;
 
 //回転の変数の準備、角度とサインコサイン
 var angle:Number = line.rotation * Math.PI/180;
 var cos:Number = Math.cos(angle);
 var sin:Number = Math.sin(angle);

 //線の基準点からのボールの位置
 var x1:Number = ball.x - line.x;
 var y1:Number = ball.y - line.y;
 
 //縦方向のみ線を水平に回転する公式
 var y2:Number = cos * y1 - sin * x1;

 //回転後、線とボールが接しているか判定
 if (y2 > -ball.height/2) {
  
  //接している場合、線にあわせる、横方向の回転、速度の回転
  y2 = -ball.height/2;
  var x2:Number = cos * x1 + sin * y1;
  var vx1:Number = cos * ball.vx + sin * ball.vy;
  var vy1:Number = cos * ball.vy - sin * ball.vx;
  
  //縦方向に跳ね返らせる
  vy1 *= bounce;
  
  //回転を元に戻す
  x1 = cos * x2 - sin * y2;
  y1 = cos * y2 + sin * x2;
  ball.vx = cos * vx1 - sin * vy1;
  ball.vy = cos * vy1 + sin * vx1;
  
  //位置を設定
  ball.x = line.x + x1;
  ball.y = line.y + y1;
 }
}