[リセット]ボタンを押すことで、再度繰り返してスタートできます。

var A:Number = Math.random()*100+10;
var B:Number = Math.random()*100+10;

var ball0:Ball = new Ball(A, Math.random()*0xffffff);
ball0.mass = A;
ball0.x = 0;
ball0.y = stage.stageHeight/2;
ball0.vx = 3;
addChild(ball0);

var ball1:Ball = new Ball(B, Math.random()*0xffffff);
ball1.mass = B;
ball1.x = stage.stageWidth;
ball1.y = stage.stageHeight/2;
ball1.vx = -3;
addChild(ball1);

addEventListener(Event.ENTER_FRAME, onEnterFrame);

function onEnterFrame(e:Event):void {
 ball0.x += ball0.vx;
 ball1.x += ball1.vx;
 var dist:Number = ball1.x - ball0.x;
 if (Math.abs(dist) < ball0.radius + ball1.radius) {
  var vx0F:Number = ((ball0.mass - ball1.mass) * ball0.vx + 2 * ball1.mass * ball1.vx)/(ball1.mass + ball0.mass);
  var vx1F:Number = ((ball1.mass - ball0.mass) * ball1.vx + 2 * ball0.mass * ball0.vx)/(ball1.mass + ball0.mass);

  ball0.vx = vx0F;
  ball1.vx = vx1F;
  ball0.x += ball0.vx;
  ball1.x += ball1.vx;

 }
 Reset_btn.addEventListener(MouseEvent.MOUSE_DOWN, onMouseDown);
}

function onMouseDown(e:Event):void {
 removeChild(ball0);
 removeChild(ball1);
 A = Math.random()*100+10;
 B = Math.random()*100+10;
 ball0 = new Ball(A, Math.random()*0xffffff);
 ball0.mass = A;
 ball0.x = 0;
 ball0.y = stage.stageHeight/2;
 ball0.vx = Math.random()*6+2;
 ball1 = new Ball(B, Math.random()*0xffffff);
 ball1.mass = B;
 ball1.y = stage.stageHeight/2;
 ball1.x = stage.stageWidth;
 ball1.vx = -Math.random()*6-2;
 addChild(ball0);
 addChild(ball1);
}

↓最適化後の部分

if (Math.abs(dist) < ball0.radius + ball1.radius) {
  var vxTotal:Number = ball0.vx - ball1.vx;
  var vx0F:Number = ((ball0.mass - ball1.mass) * ball0.vx + 2 * ball1.mass * ball1.vx)/(ball1.mass + ball0.mass);
  var vx1F:Number = vxTotal + vx0F;

 
角度のついた線との衝突判定。線が複数版です。

このFLASHの特徴はについて

• 線はランダムに配置、長さもランダム
• ボールが一定時間そこにとどまると初期位置に戻る
• 奇跡を表示します。
• 線と壁で跳ね返ります。

うまく動いたのですが、色々と値をいじっていると不自然なところがあります。
線10本。一見、エラーが内容に見えますが、線を増やすとエラーが目立ちます。


続いて、複数80本。線と下からの衝突に注目。


線の下方向からボールが当たると、突き抜ける現象があります。



最後に、ボールが大きいと、線がボールの大きさを認識してくれないバグ

var bounce:Number = -0.7;
var gravity:Number = 0.3;
var numLines:Number = 10;
var friction:Number = 0.99;
var ball:Ball = new Ball(10);
var count:int = 0;
var xball:Number = 0;
var yball:Number = 0;
var ballvx:Number = 100;
var ballvy:Number = 100;

addChild(ball);
ball.x = stage.stageWidth/2;
ball.y = 10;

//配列に線の作成と格納
var lines:Array = new Array();
for (var i:int=0; i<numLines; i++) {
 var line:Sprite = new Sprite();
 line.graphics.lineStyle(3,Math.random()*0xffffff);
 line.graphics.moveTo(0, 0);
 line.graphics.lineTo(140*Math.random()+80, 0);
 addChild(line);
 lines.push(line);
}

//線の配置処理
for (i = 0; i<numLines; i++) {
 lines[i].x = Math.random()*470;
 lines[i].y = Math.random()*350+50;
 lines[i].rotation = Math.random()*120-60;
}

//フレーム毎のイベントの追加
addEventListener(Event.ENTER_FRAME, onEnterFrame);
function onEnterFrame(e:Event):void {

 ball.vy += gravity;

 ball.vx *= friction;
 ball.vy *= friction;

 ball.x += ball.vx;
 ball.y += ball.vy;

 var right:Number = stage.stageWidth;
 var bottom:Number = stage.stageHeight;
 var r:Number = ball.radius;

 //壁との跳ね返り処理
 if (ball.x < r) {
  ball.x = r;
  ball.vx *= bounce;
 } else if (right - r < ball.x) {
  ball.x = right - r ;
  ball.vx *= bounce;
 }
 if (ball.y < r) {
  ball.y = r;
  ball.vy *= bounce;
 } else if (bottom - r < ball.y) {
  ball.y = bottom - r;
  ball.vy *= bounce;
 }
 //奇跡の表示
 graphics.beginFill(0x00cc00);
 graphics.drawCircle(ball.x, ball.y ,1);

 //線との衝突チェックの開始
 for (var i:int = 0; i<numLines; i++) {
  checkLine(lines[i]);
 }
 
// //画面上に速度を表示する。
// t1_txt.text = String(Math.round(ball.vx*100)/100);
// t2_txt.text = String(Math.round(ball.vy*100)/100);
 //t1.text = String("aaa");
 
 //フレームをカウントして一定時間移動がなければ、初期値にもどす
 count++;
 if (count>60) {
  count = 0;
  ballvx = ball.x - xball;
  ballvy = ball.y - yball;
  if (Math.abs(ballvx) < 5 && Math.abs(ballvy) < 5) {
   ball.x = stage.stageWidth*Math.random();
   ball.y = 10;
   ball.vx = 0;
   ball.vy = 0;
  }
  xball = ball.x;
  yball = ball.y;
 }
}

//チェック処理
function checkLine(line:Sprite):void {

 //線の大きさの取得
 var bounds:Rectangle = line.getBounds(this);
 if (ball.x > bounds.left && ball.x < bounds.right) {

  var angle:Number = line.rotation * Math.PI/180;
  var cos:Number = Math.cos(angle);
  var sin:Number = Math.sin(angle);

  var x1:Number = ball.x - line.x;
  var y1:Number = ball.y - line.y;

  var y2:Number = cos * y1 - sin * x1;
  var vy1:Number = cos * ball.vy - sin * ball.vx;

  //衝突時の処理
  if (y2 > -ball.height/2 && y2 < vy1) {

   var x2:Number = cos * x1 + sin * y1;

   var vx1:Number = cos * ball.vx + sin * ball.vy;
   y2 = -ball.height/2;
   vy1 *= bounce;

   x1 = cos * x2 - sin * y2;
   y1 = cos * y2 + sin * x2;
   ball.vx = cos * vx1 - sin * vy1;
   ball.vy = cos * vy1 + sin * vx1;
   ball.x = line.x + x1;
   ball.y = line.y + y1;
  }
 }
}

 

アップしてから気付いたのですが、fps（フレーム毎秒）が120のままでした（汗）

ボールの衝突判定複数版

もっと硬いボールをイメージして作ったのですが、ボールがやわらくめりこんでしまいます。

//定数は最初にまとめて定義
var numBalls:int = 20;
var bounce:Number = -0.01;
var spring:Number = 0.6;
var gravity:Number = 0.9;

//配列で個別にボールの初期位置を定義
var balls:Array = new Array();
for (var i:int = 0; i<numBalls; i++) {
 var ball:Ball = new Ball(Math.random()*40+25, Math.random() * 0x000000);
 ball.x = Math.random() * stage.stageWidth;
 ball.y = Math.random() * stage.stageHeight;
 ball.vx = Math.random() * 6-3;
 ball.vy = Math.random() * 6-3;
 addChild(ball);
 balls.push(ball);
}
addEventListener(Event.ENTER_FRAME, onEnterFrame);

function onEnterFrame(e:Event):void {
 //配列で個別に計算
 for(var i:int = 0; i< numBalls - 1; i++){
  var ball0:Ball = balls[i];
  for(var j:int = i + 1; j< numBalls; j++){
   var ball1:Ball = balls[j];
   var dx:Number = ball1.x - ball0.x;
   var dy:Number = ball1.y - ball0.y;
   var dist:Number = Math.sqrt(dy*dy + dx*dx);
   var minDist:Number = ball0.radius + ball1.radius;

 //真中のボールと衝突したときの跳ね返り
   if (dist<minDist) {
    var angle:Number = Math.atan2(dy, dx);
    var tx:Number = ball0.x + Math.cos(angle) * minDist;
    var ty:Number = ball0.y + Math.sin(angle) * minDist;
    var ax:Number = (tx - ball1.x) * spring;
    var ay:Number = (ty - ball1.y) * spring;
    ball0.vx -= ax;
    ball0.vy -= ay;
    ball1.vx += ax;
    ball1.vy += ay;

   }
  }
 }
 for(i = 0; i<numBalls; i++){
  var ball:Ball = balls[i];
  move(ball);
 }
}

//ボールの運動は切り離して計算
function move(ball:Ball):void {
 ball.vy += gravity;
 ball.x += ball.vx;
 ball.y += ball.vy;
 
 //ステージ端の跳ね返り
 if (ball.x < ball.radius) {
  ball.x = ball.radius;
  ball.vx *= bounce;
 } else if (ball.x > stage.stageWidth - ball.radius) {
  ball.x = stage.stageWidth - ball.radius;
  ball.vx *= bounce;
 }
 if (ball.y < ball.radius) {
  ball.y = ball.radius;
  ball.vy *= bounce;
 } else if (ball.y > stage.stageHeight - ball.radius) {
  ball.y = stage.stageHeight - ball.radius;
  ball.vy *= bounce;
 }
}